如何禁用宏则隐藏工作簿全部内容？

作者：绿色风分类：时间：2022-08-17 浏览：121

楼主
kevinchengcw

Q: 如何禁用宏则隐藏工作簿全部内容？
A: 思路如下：关闭工作簿前执行代码将除活动工作表外的全部工作表深度隐藏（这样普通方式没办法找出深度隐藏的工作表），将当前活动工作表全部行隐藏，并隐藏工作簿的标签等，代码如下：

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim Ws As Worksheet
Application.ScreenUpdating = False '关闭屏幕刷新，提高处理速度的同时隐藏工作时内容
For Each Ws In Worksheets '循环工作簿中各个工作表
If Ws.Name <> ActiveSheet.Name Then Ws.Visible = xlSheetVeryHidden '如果不是当前活动工作表则尝试隐藏
Next Ws
ActiveWindow.DisplayWorkbookTabs = False '隐藏工作簿标签栏
ActiveWindow.DisplayHeadings = False '隐藏行列标签栏
ActiveSheet.Range("a1:a" & Rows.Count).EntireRow.Hidden = True '活动工作表全部行隐藏
ThisWorkbook.Save '保存修改后的结果
Application.ScreenUpdating = True '打开屏幕刷新
End Sub

启动工作簿时如果启用宏则执行上面代码的逆进程，代码如下：

Private Sub Workbook_Open()
Dim Ws As Worksheet
Application.ScreenUpdating = False
For Each Ws In Worksheets
If Ws.Name <> ActiveSheet.Name Then Ws.Visible = xlSheetVisible
Next Ws
ActiveWindow.DisplayWorkbookTabs = True
ActiveWindow.DisplayHeadings = True
ActiveSheet.Range("a1:a" & Rows.Count).EntireRow.Hidden = False
Application.ScreenUpdating = True
End Sub

通过以上方法处理的文件，如果对方不启用宏则无法看到工作簿内容，但是安全是相对的，对于懂得VBA的人只是小菜一碟。

2楼
水星钓鱼

是个方法。

3楼
开心二点

K哥V5ing

免责声明

有感于原ExcelTip.Net留存知识的价值及部分知识具有的时间限定性因素，经与ExcelTip.Net站长Apolloh商议并征得其同意，现将原属ExcelTip.Net的知识帖采集资料于本站点进行展示，供有需要的人士查询使用，也慰缅曾经的论坛时代。所示各个帖子的原作者如对版权有异议，可与本人沟通提出，或于本站点留言，我们会尽快处理。在此，感谢ExcelTip.Net站长Apolloh的支持，感谢本站点所有人**绿色风（QQ:79664738)**的支持与奉献，特此鸣谢！
------本人网名**KevinChengCW（QQ:1210618015)**原ExcelTip.Net总版主之一

评论列表