如何依完成信息提取对应物品号段并计数?

作者：绿色风分类：时间：2022-08-17 浏览：69

楼主
liuguansky

Q:这里有三个表，想提取每个表完成情况的编号好统计数据，怎么才可以做到啊？
A:用如下代码可以实现:

Sub justtst()
Dim arr, i&, U As Byte, arrt(), k&, j& '定义变量
For U = 1 To Sheets.Count '循环工作表
If Sheets(U).Name <> "Sheet1" Then '对非汇总工作表判断
With Sheets(U) '获取工作表对象
k = k + 1: ReDim Preserve arrt(1 To 3, 1 To k) '一个表返回一条记录|即结果动态数组进行增维
arrt(1, k) = .Name '赋值班组
arr = .Range("A2").Resize(.Cells(.Rows.Count, 1).End(3).Row, 3).Value '获取工作表区域
For i = 1 To UBound(arr, 1) - 1 '循环数组区域
If arr(i, 3) <> "" Then '判断是否完成
arrt(2, k) = arrt(2, k) & " " & arr(i, 2) '完成则进行后面项目赋值
arrt(3, k) = arrt(3, k) + 1
j = i
Do While arr(i + 1, 3) <> "" '判断是否连续完成
i = i + 1
Loop
If i > j Then '对连续完成项目进行合并,个数累加
arrt(2, k) = arrt(2, k) & "-" & arr(i, 2)
arrt(3, k) = arrt(3, k) + i - j
End If
End If
Next i
End With
End If
Next
Range("a2:c" & Rows.Count).ClearContents
Range("A2").Resize(k, 3) = Application.Transpose(arrt)
End Sub

2楼
tangwei94054

谢谢老师啊，还被评分了。谢谢

免责声明

有感于原ExcelTip.Net留存知识的价值及部分知识具有的时间限定性因素，经与ExcelTip.Net站长Apolloh商议并征得其同意，现将原属ExcelTip.Net的知识帖采集资料于本站点进行展示，供有需要的人士查询使用，也慰缅曾经的论坛时代。所示各个帖子的原作者如对版权有异议，可与本人沟通提出，或于本站点留言，我们会尽快处理。在此，感谢ExcelTip.Net站长Apolloh的支持，感谢本站点所有人**绿色风（QQ:79664738)**的支持与奉献，特此鸣谢！
------本人网名**KevinChengCW（QQ:1210618015)**原ExcelTip.Net总版主之一

评论列表