作者：绿色风
分类：
时间：2022-08-17
浏览：123
楼主
gouweicao78 |
Q：已知年份在A1，要求第n周（n输入在A2）的日期范围是从几月几日到几月几日。
A：某年第n周的起始日期：
- =MAX(DATE(A1,1,1),DATE(A1,1,1)-WEEKDAY(DATE(A1,1,1),2)+(A2-1)*7+1)
即用当年1月1日上一周的周日加上(n-1)*7+1天，并用MAX将下限设置为1月1日。
终止日期为：
- =MIN(DATE(A1+1,1,0),DATE(A1,1,1)-WEEKDAY(DATE(A1,1,1),2)+A2*7)
|
2楼
gouweicao78 |
再给简化解法：
第n周起始日期
- =MAX((A1&-1)-MOD(A1&-1,7)-5+7*A2,A1&-1)
终止日期
- =MIN((A1&-1)-MOD(A1&-1,7)+1+7*A2,((A1+1)&-1)-1)
|
3楼
rongjun |
2楼公式错了吧？
如果以星期一为每周开始，公式修改如下（假设A3为年份，B3为第n周）：
开始日期：
- =MAX((A3&-1)-MOD((A3&-1)-2,7)-7+7*B3,A3&-1)
结束日期：
- =MIN((A3&-1)-MOD((A3&-1)-2,7)+7*B3-1,(A3+1&-1)-1)
|
4楼
rongjun |
再给个简化公式：
开始日期：- =MAX(FLOOR((A3&-1)-2,7)-5+7*B3,A3&-1)
结束日期：- =MIN(FLOOR((A3&-1)-2,7)+1+7*B3,(A3+1&-1)-1)
|
5楼
chrisfang |
开始日期：
- =(A1&-1)-WEEKDAY(A1&-1)+A2*7-5
结束日期：
- =(A1&-1)-WEEKDAY(A1&-1)+A2*7+1
我在这个帖子里用过：Excel版记事日历 http://www.exceltip.net/thread-6889-1-1.html
|
6楼
rongjun |
方版，你的公式有误吧？ |
7楼
chrisfang |
以周一为起始，可以试一下以下公式：
起始日：
- =(A1&-1)-WEEKDAY(A1&-1,2)+A2*7-6
终止日：
- =(A1&-1)-WEEKDAY(A1&-1,2)+A2*7
如果以周日为起始，可以使用以下公式：
起始日：
- =(A1&-1)-WEEKDAY(A1&-1)+A2*7-6
终止日：
- =(A1&-1)-WEEKDAY(A1&-1)+A2*7
|
8楼
chrisfang |
哦，之前没仔细看你们的公式，你们是仅计算当年的日期哦，那就是计算第一周和最后一周的时候会有些出入。 |
9楼
ccf |
精彩！ |
10楼
tieqilin |
太棒了，收藏 |
免责声明
有感于原ExcelTip.Net留存知识的价值及部分知识具有的时间限定性因素，
经与ExcelTip.Net站长Apolloh商议并征得其同意，
现将原属ExcelTip.Net的知识帖采集资料于本站点进行展示，
供有需要的人士查询使用，也慰缅曾经的论坛时代。
所示各个帖子的原作者如对版权有异议，
可与本人沟通提出，或于本站点留言，我们会尽快处理。
在此，感谢ExcelTip.Net站长Apolloh的支持，感谢本站点所有人**绿色风（QQ:79664738)**的支持与奉献，特此鸣谢！
------本人网名**KevinChengCW（QQ:1210618015)**原ExcelTip.Net总版主之一