使用类模块时变量应该如何定义？

楼主
amulee

Q：使用类模块时变量应该如何定义？
A：本例中，在类模块“类1”中有如下代码：

Option Explicit
Public WithEvents cmd As CommandButton
Private Sub cmd_Click()
MsgBox "我是靠类模块属性的事件激活的，我的标题名称是" & cmd.Caption
End Sub

窗体中有两个按钮，现在需要实现利用该类模块给这两个按钮定义点击事件。代码如下：

Option Explicit
Private Sub UserForm_Initialize()
Dim myCls1 As 类1 '定义类1的对象变量myCls1
Dim myCls2 As 类1 '定义类1的对象变量myCls2
Set myCls1 = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myCls1
Set myCls2 = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myCls2
'下面的这个语句，就把CommandButton1，CommandButton2这两个按钮对象的事件“出卖”给了myCls1和myCls2的属性
Set myCls1.cmd = Me.CommandButton1 '把对CommandButton1对象的引用赋值给myCls1的属性cmd
Set myCls2.cmd = Me.CommandButton2 '把对CommandButton2对象的引用赋值给myCls2的属性cmd
End Sub

当运行窗体的时候，代码不起作用。
这是一个类模块初学者常犯的错误。究其原因，是变量的作用域和生存期搞的鬼。本例中的myCls1和myCls2两个变量定义在UserForm_Initialize过程中，所以其作用域和生存期仅存在于UserForm_Initialize该过程中，一旦该过程执行结束，这两个变量就不存在。当然也就无法实现窗体运行过程中按钮单击代码的类模块实现。

所以，如果在窗体中绑定类模块，必须要考虑该变量的生存期以及作用域。可以将窗体代码更改如下：

Option Explicit
Dim myCls1 As 类1 '定义类1的对象变量myCls1
Dim myCls2 As 类1 '定义类1的对象变量myCls2
Private Sub UserForm_Initialize()
Set myCls1 = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myCls1
Set myCls2 = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myCls2
'下面的这个语句，就把CommandButton1，CommandButton2这两个按钮对象的事件“出卖”给了myCls1和myCls2的属性
Set myCls1.cmd = Me.CommandButton1 '把对CommandButton1对象的引用赋值给myCls1的属性cmd
Set myCls2.cmd = Me.CommandButton2 '把对CommandButton2对象的引用赋值给myCls2的属性cmd
End Sub

如此，将变量独立于各过程之外，其生存周期为窗体整个运行期间。或者添加一个标准模块，添加以下代码：

Public myCls1 As 类1 '定义类1的对象变量myCls1
Public myCls2 As 类1 '定义类1的对象变量myCls2

定义两个全局变量，以保证工作簿打开期间该变量都有效。

综上所述，类模块在使用的时候必须考虑变量的作用域和生存期，才能使类模块实现预期效果。

有关变量作用域和生存期的理解，请参考下贴：
[Excel VBA] VBA 中变量的作用域和生存期是怎么样理解的？ http://www.exceltip.net/thread-5946-1-1.html

关于类模块中的事件没有执行的问题.rar

2楼
wbzxz

谢谢amulee老师，想想这种问题我都犯过好几次错误啦，每次都不一样，综合起来都是变量作用域的问题，以前没有注意过，但是运用类模块的时候，这个问题还真的需要好好注意呢。
其实我感觉上次那个窗体控件高亮中我犯的那个错误（key_down,key_up事件），更能体现出变量作用域的问题，您也采编过来吧，嘿嘿。

3楼
水星钓鱼

这个问题今天也碰到了，初学者