楼主
Zaezhong |
用公式生成下图的效果，在A2输入公式后下拉
要求与评分：- 公式用代码框贴出，否则不评分
- 正确答案即可获得基础分（基础分为2魅力值），按照公式的思路给分
- 使用“&”或者CONCATENATE函数的一概获得基本分（虽然有舍近求远的感觉，主要是挖掘新的思路）
- 满足3的同时，如果可以填充至65536行，而不修改公式额外给1技能分
期限：暂定半月
题目简单，欢迎大家参与 |
2楼
xiongkehua2008 |
- A2=ROW()*2-1&"-"&ROW()*2
|
3楼
天南地北 |
先贴一个个公式，在A1，输入即可，如果把row()换成ROW(A1)可以在任意单元格输入
公式一：- =TEXT((ROW()*2-1)*10^LEN(ROW()*2)+ROW()*2,0&"-"&REPT(0,LEN(ROW()*2)))
公式二：- =ROW()*2-1&"-"&ROW()*2
公式三：
- =CONCATENATE(ROW()*2-1,"-",ROW()*2)
|
4楼
tntpai |
- =TEXT(REPT((ROW()*2),2)-10^LEN(ROW()*2),IF(ROW()>4,"0-00","0-0"))
- =TEXT((ROW()*2-1)*10^LEN(ROW()*2)+ROW()*2,IF(ROW()>4,"0-00","0-0"))
- =SUBSTITUTE(TEXT((ROW()*2-1)+ROW()/IF(ROW()<5,5,50),IF(ROW()<5,"0.0","0.00")),".","-")
|
5楼
Zaezhong |
- =SUBSTITUTE(TEXT(1-1/ROW()/2,"0/#####0"),"/","-")
预设答案，可以一直填充到2003版本的最后一行 |
6楼
lrlxxqxa |
- =2*(ROW()-1)+1&"-"&2*(ROW()-1)+2
|
7楼
dalianyingzi |
- =ROW()*2-1&"-"&2*ROW()
|
8楼
w83365040371 |
- =SUBSTITUTE(TEXT(1-1/(2*ROW()),"0/#####0"),"/","-")
|
9楼
终点 |
- =(ROW()*2-1)&-(ROW()*2)，
- =CONCATENATE(ROW()*2-1,"-",ROW()*2)
|
10楼
peakchu |
- =REPLACE(REPLACE(G13,LEN(G13)+1,,"-"),LEN(G13)+2,,ROW()*2)
|
11楼
herelazy |
向下填充，我只能获得基础分，呵呵！- =LEFT(A1,FIND("-",A1)-1)+2&"-"&MID(A1,FIND("-",A1)+1,9^9)+2
|
12楼
peakchu |
- =REPLACE(REPLACE(ROW()*2-1,LEN(ROW()*2-1)+1,,"-"),LEN(ROW()*2-1)+2,,ROW()*2)
|
13楼
piny |
用&- =ROW()*2-1&-ROW()*2
不用&- =SUBSTITUTE(REPT(-ROW()*2,2),-ROW()*2,ROW()*2-1,1)
或- =SUBSTITUTE(SUBSTITUTE(A1,ROW()*2-2,ROW()*2),ROW()*2-3,ROW()*2-1)
|
14楼
gouweicao78 |
- =ROW()*2-1&-ROW()*2
|
15楼
鬼狐 |
- =REPLACE((ROW()*2-1)*10^LEN(ROW()*2)+ROW()*2,LEN(ROW()*2-1)+1,,"-")
|
16楼
传递 |
我试了三种方法
1.- =ROW()*2-1&"-"&ROW()*2
2.- =CONCATENATE(D1,"-", E1)
用辅助列产生奇数 偶数
3。- N2==SUM(O1+1)
- 02=SUM(O1+2)
- P2==N2&"-"&O2
用辅助列（ 不推荐，我只是想锻炼自己思路，和学更多方法。请版主 多多指导） |
17楼
bensonlei |
- A2=ROW()*2-1&"-"&ROW()*2
|
18楼
hopeson2010 |
- =SUBSTITUTE(TEXT(ROW()*2-1,SUBSTITUTE(TEXT(ROW()*2,"\#-#"),0,"A")),"A",0)
|
19楼
卢子 |
水平有限只能用这个- =(LEFT(A1,FIND("-",A1)-1)+2)&"-"&(RIGHT(A1,LEN(A1)-FIND("-",A1))+2)
|
20楼
lhq-2000 |
先挣点魅力值再说：
=ROW()*2-1&"-"&ROW()*2 |
21楼
larkzh |
- =1+(ROW()-ROW($A$1))*2&"-"&ROW()*2
|
22楼
Zaezhong |
昨天的意外，提前开帖，评分完成，有问题请提出
预设的答案在5楼。本题主要是想大家在数列上考虑通项公式，直接用&的公式比较基础，不再点评
- =SUBSTITUTE(TEXT(1-1/ROW()/2,"0/#####0"),"/","-")
要求公式填充到65536行，通过研究每一行的数，我们发现，每一个数都是1-1/(ROW()*2)，这样就得出了通项公式，由于每一个项的长度不同，所以用到了自定义格式中的“#”，但需要添加位数的时候就自动添加，而不会显示没有必要的其他字符。
也有几位参与者给出了比较新颖的答案，13楼piny老师的第二个答案就比较好，思路也比较简洁，在此感谢各位的参与~~ |
23楼
bensonlei |
刚想了一个新的, 还有分加吗?- =REPLACE(REPLACE(ROW()*2-1,LEN(ROW()*2-1)+1,0,"-"),LEN(REPLACE(ROW()*2-1,LEN(ROW()*2-1)+1,0,"-"))+1,0,ROW()*2)
|
24楼
bensonlei |
不好意思, 不知道已开题! |
25楼
lhq-2000 |
当时不知道怎么使用代码啦，现在补上
- =ROW()*2-1&"-"&ROW()*2
|