楼主
悟空师弟 |
题目：用条件格式自动标出重复安排到两个（及以上）考场的监考员。
规则：同一监考员安排在同一科目（即同行）的不同考场则视为重复安排。
答题时限：（截止日期，2010年12月1日，到期后公布答案）
详见附件：
 标出有重复安排的监考员.rar
附图：
-----------------------------------------------------
暂时先公布各楼层的答案，稍候评分！ |
2楼
mxqchina |
b4条件格式：
=COUNT(0/(FREQUENCY(IF(($B4:$Y4=B4)*($B4:$Y4<>""),--SUBSTITUTE(MID($B$1:$Y$1,2,4),"考场",)),IF($B4:$Y4=B4,--SUBSTITUTE(MID($B$1:$Y$1,2,4),"考场",)))))>1
标出有重复安排的监考员999.rar
|
3楼
rongjun |
条件格式- =(COUNT(MATCH("第"&ROW($1:$15)&"考场",IF($B4:$Y4=B4,$B$1:$Y$1),))>1)*(B4<>"")
标出有重复安排的监考员.rar
|
4楼
gouweicao78 |
选B4:Y13单元格区域，设置条件格式，公式为：- =SUM(($B$1:$Y$1<>B$1)*($B4:$Y4=B4))
|
5楼
水星钓鱼 |
选中单元格区域B4:Y13
条件格式中选择使用公式确定要设置格式的单元格
输入公式：
- =AND(COUNTIF($B4:$Y4,B4)<>SUM(--(B4&B$1=$B4:$Y4&$B$1:$Y$1)),LEN(B4)>0)
标出有重复安排的监考员_水星钓鱼.rar
|
6楼
liuguansky |
- =(B4<>"")*COUNT(0/(MATCH(B4&$B$1:$Y$1,$B4:$Y4&$B$1:$Y$1,)=COLUMN($A:$X)))>1
明显是我昨天解答的一个问题改编的。。
标出有重复安排的监考员.rar
|
7楼
biaotiger1 |
条件格式中输入公式- =IF(COUNTIF($B4:$Y4,B4)>1,LARGE(FREQUENCY((SMALL(IF($B4:$Y4=B4,--MID($B$1:$Y$1,2,2*LEN($B$1:$Y$1)-LENB($B$1:$Y$1)),),ROW($1:$24))),ROW($1:$24)),3))
应该不会这么长的吧？
标出有重复安排的监考员.rar
|
8楼
mn860429 |
- =COUNT(0/(FREQUENCY(IF($B4:$Y4=B4,--SUBSTITUTE(MID($B$1:$Y$1,2,5),"考场",),),IF($B4:$Y4=B4,--SUBSTITUTE(MID($B$1:$Y$1,2,5),"考场",),))))>2
标出有重复安排的监考员.rar
|
9楼
战神一啸 |
我也下下来试试! |
10楼
Zaezhong |
B4条件格式- =(COUNTIF(OFFSET($A$1,,MIN(IF($B4:$Y4=B4,COLUMN($A:$X))),,MAX(IF($B4:$Y4=B4,COLUMN($A:$X)))-MIN(IF($B4:$Y4=B4,COLUMN($A:$X)))+1),B$1)<>SUM(($B4:$Y4=B4)/1))*(B4<>"")
附件删除了效果表，将条件格式的公式写在下方
- =(COUNTIF(OFFSET($A$1,,MIN(IF($B4:$Y4=B4,COLUMN($A:$X))),,MAX(IF($B4:$Y4=B4,COLUMN($A:$X)))-MIN(IF($B4:$Y4=B4,COLUMN($A:$X)))+1),B$1)<>COUNTIF($B4:$Y4,B4))*(B4<>"")
标出有重复安排的监考员.rar
|
11楼
zm0115 |
=SUMPRODUCT((B4<>"")*($B4:$Y4=B4)*($B$1:$Y$1<>B$1))
标出有重复安排的监考员.rar
|
12楼
LOGO |
选中B4:Y13单元格区域
设置条件格式为- =INDEX($B$1:$Y$1,MATCH(B4,$B4:$Y4,0))<>LOOKUP(1,0/($B4:$Y4=B4),$B$1:$Y$1)
,
利用match在lookupvalue有多个符合条件时返回第一个,而lookup返回的是最后一个这一不同之处.
标出有重复安排的监考员.rar
|
13楼
涅磐86970 |
B4:Y13
=SUMPRODUCT(($B4:$Y4=B4)*($B$1:$Y$1<>B$1)*(B4<>"")) |
14楼
Deksan |
使用条件公式：
=IF(COUNTIF($B4:$Y4,B4)>1,1,0)
设定背景色为红色 确认 然后使用格式刷刷需要的数据区域
题目看错了 没看到 第一行 有重复场次条件格式标出重复项.gif
 |
15楼
君柳 |
=SUMPRODUCT((MATCH($B$1:$Y$1&$B4:$Y4,$B$1:$Y$1&$B4:$Y4,)=COLUMN($B$1:$Y$1)-1)*($B4:$Y4=B4)*(B4<>""))>1 |
16楼
omnw |
标出有重复安排的监考员.rar
|
17楼
悟空师弟 |
各楼层答案如下：
| 楼层 | ID | 结果 | 公式 | | 2楼： | mxqchina
| 正确 |
=COUNT(0/(FREQUENCY(IF(($B4:$Y4=B4)*($B4:$Y4<>""),--SUBSTITUTE(MID($B$1:$Y$1,2,4),"考场",)),IF($B4:$Y4=B4,--SUBSTITUTE(MID($B$1:$Y$1,2,4),"考场",)))))>1 | | 3楼： | rongjun
| 正确 |
=(COUNT(MATCH("第"&ROW($1:$15)&"考场",IF($B4:$Y4=B4,$B$1:$Y$1),))>1)*(B4<>"") | | 4楼： | gouweicao78
| 错误，没有考虑空单元格。 |
=SUM(($B$1:$Y$1<>B$1)*($B4:$Y4=B4)) | | 5楼： | 水星钓鱼
| 正确 |
=AND(COUNTIF($B4:$Y4,B4)<>SUM(--(B4&B$1=$B4:$Y4&$B$1:$Y$1)),LEN(B4)>0) | | 6楼： | liuguansky
| 正确 |
=(B4<>"")*COUNT(0/(MATCH(B4&$B$1:$Y$1,$B4:$Y4&$B$1:$Y$1,)=COLUMN($A:$X)))>1 | | 7楼： | biaotiger1
| 正确 |
=IF(COUNTIF($B4:$Y4,B4)>1,LARGE(FREQUENCY((SMALL(IF($B4:$Y4=B4,--MID($B$1:$Y$1,2,2*LEN($B$1:$Y$1)-LENB($B$1:$Y$1)),),ROW($1:$24))),ROW($1:$24)),3)) | | 8楼： | mn860429 | 错误，没有考虑空单元格。 |
=COUNT(0/(FREQUENCY(IF($B4:$Y4=B4,--SUBSTITUTE(MID($B$1:$Y$1,2,5),"考场",),),IF($B4:$Y4=B4,--SUBSTITUTE(MID($B$1:$Y$1,2,5),"考场",),))))>2 | | 9楼： | 战神一啸
| 无答案 | | | 10楼： | Zaezhong
| 正确 |
=(COUNTIF(OFFSET($A$1,,MIN(IF($B4:$Y4=B4,COLUMN($A:$X))),,MAX(IF($B4:$Y4=B4,COLUMN($A:$X)))-MIN(IF($B4:$Y4=B4,COLUMN($A:$X)))+1),B$1)<>SUM(($B4:$Y4=B4)/1))*(B4<>"") | | 11楼： | zm0115
| 正确 |
=SUMPRODUCT((B4<>"")*($B4:$Y4=B4)*($B$1:$Y$1<>B$1)) | | 12楼： | LOGO
| 正确 |
=INDEX($B$1:$Y$1,MATCH(B4,$B4:$Y4,0))<>LOOKUP(1,0/($B4:$Y4=B4),$B$1:$Y$1) | | 13楼： | 涅磐86970
| 正确 |
=SUMPRODUCT(($B4:$Y4=B4)*($B$1:$Y$1<>B$1)*(B4<>"")) | | 14楼： | Deksan
| 错误 |
=IF(COUNTIF($B4:$Y4,B4)>1,1,0) | | 15楼： | 君柳
| 正确 |
=SUMPRODUCT((MATCH($B$1:$Y$1&$B4:$Y4,$B$1:$Y$1&$B4:$Y4,)=COLUMN($B$1:$Y$1)-1)*($B4:$Y4=B4)*(B4<>""))>1 | | 16楼： | omnw
| 错误 |
=COUNTIF($B4:$Y4,B4)>=2 |
免责声明 有感于原ExcelTip.Net留存知识的价值及部分知识具有的时间限定性因素，
经与ExcelTip.Net站长Apolloh商议并征得其同意，
现将原属ExcelTip.Net的知识帖采集资料于本站点进行展示，
供有需要的人士查询使用，也慰缅曾经的论坛时代。
所示各个帖子的原作者如对版权有异议，
可与本人沟通提出，或于本站点留言，我们会尽快处理。
在此，感谢ExcelTip.Net站长Apolloh的支持，感谢本站点所有人**绿色风（QQ:79664738)**的支持与奉献，特此鸣谢！
------本人网名**KevinChengCW（QQ:1210618015)**原ExcelTip.Net总版主之一 |