如何对VBA数组按照自定义序列排序？

作者：绿色风分类：时间：2022-08-17 浏览：158

楼主
amulee

Q：如何对VBA数组按照自定义序列排序？
A：本例中，数组来源为表格中B:AB列的数据，要求根据C列按自定义序列进行排序。
本例解决方案为数组排序解法，将自定义序列定义为数组，原始数组关键字与该序列数组进行比对找出相应位置，然后根据该位置进行排序比较。
参考代码如下：

Sub MySort()
Dim KeyWD As String
Dim ArrKey, ArrYS, ArrTemp
Dim i&, j&, Temp, Pos1, Pos2
'自定义序列
KeyWD = "外妇科|手术室|内儿科|西医科|中医科|耳鼻喉科|放射科|检验科|B超室|口腔科|针灸科|西药房|中药房|收费室|疾控科|合管办|后勤科"
ArrKey = Split(KeyWD, "|")
'定义原始数组、临时数组（用于交换值）
ArrYS = Sheet1.Range("B2:AB" & Sheet1.Range("B" & Cells.Rows.Count).End(xlUp).Row)
ReDim ArrTemp(1 To 1, 1 To UBound(ArrYS, 2))
'冒泡排序法
'开始遍历原始数组
For i = 1 To UBound(ArrYS) - 1
'获取当前元素的在序列中的大小，及当前位置
Pos1 = WorksheetFunction.Match(ArrYS(i, 2), ArrKey, 0)
Temp = i
'遍历剩余的元素
For j = i + 1 To UBound(ArrYS)
'获取序列中的大小
Pos2 = WorksheetFunction.Match(ArrYS(j, 2), ArrKey, 0)
If Pos2 < Pos1 Then
Pos1 = Pos2
Temp = j
End If
Next j
'如果记录序列中最小值的记录位置不是当前的位置，则交换
If Temp <> i Then
For j = 1 To UBound(ArrTemp, 2)
ArrTemp(1, j) = ArrYS(i, j)
Next j
For j = 1 To UBound(ArrTemp, 2)
ArrYS(i, j) = ArrYS(Temp, j)
Next j
For j = 1 To UBound(ArrTemp, 2)
ArrYS(Temp, j) = ArrTemp(1, j)
Next j
End If
Next
'结果输出
Sheet1.Range("B2:AB" & Sheet1.Range("B" & Cells.Rows.Count).End(xlUp).Row) = ArrYS
End Sub

将数组按照自定义序列排序.rar

2楼
亡者天下

不错，过来学习一下

免责声明

有感于原ExcelTip.Net留存知识的价值及部分知识具有的时间限定性因素，经与ExcelTip.Net站长Apolloh商议并征得其同意，现将原属ExcelTip.Net的知识帖采集资料于本站点进行展示，供有需要的人士查询使用，也慰缅曾经的论坛时代。所示各个帖子的原作者如对版权有异议，可与本人沟通提出，或于本站点留言，我们会尽快处理。在此，感谢ExcelTip.Net站长Apolloh的支持，感谢本站点所有人**绿色风（QQ:79664738)**的支持与奉献，特此鸣谢！
------本人网名**KevinChengCW（QQ:1210618015)**原ExcelTip.Net总版主之一

评论列表