楼主 kevinchengcw |
Q: 如何根据发_票号取得对应发_票组联的发_票简写名及金额? A: 本例引用一个实例作为一个多项高级功能综合应用的实例,利用代码根据发_票联号的规律找出对应的登记名和金额,代码如下:- Sub test()
- Dim Str As String
- Dim Dic, Arr, RegEx
- Dim M, N, I As Long
- Set Dic = CreateObject("scripting.dictionary") '定义字典,用于存储发_票号及相关数据
- Set RegEx = CreateObject("vbscript.regexp") '定义正则表达式,用于去除登记名中的汉字
- With RegEx '设定正则表达式相关参数
- .Global = True '全程有效
- .Pattern = "[\u4e00-\u9fa5]" '匹配条件为全部中文字符
- End With
- With Worksheets("金蝶") '先于登记的工作表中处理数据
- For N = 2 To Cells(Rows.Count, 2).End(3).Row '设定在登记工作表中的循环范围
- If .Cells(N, 2) <> "" Then '如果当前行的B列不为会,即登记项不为空,则进行下述操作
- Str = RegEx.Replace(.Cells(N, 2).Value, "") '用正则表达式替换掉B列单元格文本中的全部汉字并赋值给字符串变量
- Do While InStr(Str, "--") > 0 '循环替换全部的两个相连的“-”为一个,防止误输入两个后出错
- Str = Replace(Str, "--", "-")
- Loop
- Str = Replace(Str, "#", "/") '将字符串中的#替换成"/",主要因为如果中间夹杂汉字的话如果替换为空会将两串数字连接起来,所以换成特定的分割字符
- If InStr(Str, "/") > 0 Then '判断字符串是不是由多个数字串组成
- Arr = Split(Str, "/") '是的话就根据特定字符分割放入数组
- Else
- ReDim Arr(0) '否则将数组定义为只有一个项(不这样定义会出错)
- Arr(0) = Str '将字符串赋值给数组
- End If
- For M = LBound(Arr) To UBound(Arr) '循环提取数组内容
- If Arr(M) <> "" Then '如果对应数组内容不为空,则进一步操作
- If InStr(Arr(M), "-") > 0 Then '如果数组当前项含有“-”号,说明是简写模式,要进行展开
- For I = Val(Split(Arr(M), "-")(0)) To Val(Left(Split(Arr(M), "-")(0), Len(Split(Arr(M), "-")(0)) - Len(Split(Arr(M), "-")(1))) & Split(Arr(M), "-")(1)) '设定变量是从"-"的前一个值到后一个值之间,注意后一个值的获得方式
- If Not Dic.exists(Format(I, "00000000")) Then _
- Dic.Add Format(I, "00000000"), .Cells(N, 2).Value & vbTab & .Cells(N, 3).Value '如果字典中没有当前值的key则添加当前值,及对应的B列和C列的值组成的Item项(用特定字符分隔,方便后面提取),注意key 的格式,否则在后面可能出错
- Next I
- Else
- If Not Dic.exists(Format(Arr(M), "00000000")) Then _
- Dic.Add Format(Arr(M), "00000000"), .Cells(N, 2).Value & vbTab & .Cells(N, 3).Value '如果不是缩写模式,直接将数组当前值添加进字典
- End If
- End If
- Next M
- Erase Arr '数组用完后清空,防止出错
- End If
- Next N
- End With
- With Worksheets("税务局认证") '再到结果页来写入数值
- For N = 2 To .Cells(Rows.Count, 1).End(3).Row '设定循环范围
- If Dic.exists(.Cells(N, 1).Value) Then '如果A列当前行的值与字典中的key相吻合则
- .Cells(N, 5) = Format(Split(Dic(.Cells(N, 1).Value), vbTab)(0), "00000000") '依特定字符分割item项并格式化输出到对应单元格
- .Cells(N, 6) = Format(Split(Dic(.Cells(N, 1).Value), vbTab)(1), "0.00")
- End If
- Next N
- End With
- Set Dic = Nothing '清空项目,释放内存
- Set RegEx = Nothing
- End Sub
总结: 以上代码涉及到如下知识点: 1. 字典的应用 2. 正则的应用 3. 简缩码转全码的方法应用
希望这篇文章能帮助大家学习这方面的用法。 附示例文件。
发票.rar |