关于查找单元格区域中特定字符个数的几种VBA方法

作者：绿色风分类：时间：2022-08-18 浏览：315

楼主
liuguansky

一、数组循环判断

Sub 单击() '数组循环判断
Dim arr, i&, j&, s&
arr = Cells(1, 1).CurrentRegion.Value
s = 0
For i = 1 To UBound(arr, 1)
For j = 1 To UBound(arr, 2)
If arr(i, j) = "正常" Then
s = s + 1
End If
Next j, i
MsgBox "共有正常个数为：" & s
End Sub

二、工作表函数

Sub 单击1() '工作表函数
MsgBox "共有正常个数为：" & Application.WorksheetFunction.CountIf(Cells(1, 1).CurrentRegion, "正常")
End Sub

三、VBA　filter函数

Sub 单击2() 'filter函数
Dim arr, i&, arrt, s&
arr = Cells(1, 1).CurrentRegion.Value
s = 0
For i = 1 To UBound(arr, 2)
arrt = Filter(Application.Transpose(Application.Index(arr, , i)), "正常")
s = s + UBound(arrt) + 1
Next i
MsgBox "共有正常个数为：" & s
End Sub

　
四、字典

Sub 单击3() '字典
Dim arr, i&, j&, dic
Set dic = CreateObject("scripting.dictionary")
arr = Cells(1, 1).CurrentRegion.Value
For i = 1 To UBound(arr, 1)
For j = 1 To UBound(arr, 2)
If arr(i, j) <> "" Then
If dic.exists(arr(i, j)) Then
dic(arr(i, j)) = dic(arr(i, j)) + 1
Else: dic.Add arr(i, j), 1
End If
End If
Next j, i
If dic.exists("正常") Then
MsgBox "共有正常个数为：" & dic("正常")
Else: MsgBox "未找到正常记录"
End If
Set dic = Nothing
End Sub

桌面.rar

欢迎大家补充。

2楼
wise

Sub test()
With Range("A1:G1000")
Set c = .Find("正常", LookIn:=xlValues)
If Not c Is Nothing Then
firstAddress = c.Address
Do
i = i + 1
Set c = .FindNext(c)
Loop While Not c Is Nothing And c.Address <> firstAddress
End If
MsgBox "共有正常个数为：" & i
End With
End Sub

免责声明

有感于原ExcelTip.Net留存知识的价值及部分知识具有的时间限定性因素，经与ExcelTip.Net站长Apolloh商议并征得其同意，现将原属ExcelTip.Net的知识帖采集资料于本站点进行展示，供有需要的人士查询使用，也慰缅曾经的论坛时代。所示各个帖子的原作者如对版权有异议，可与本人沟通提出，或于本站点留言，我们会尽快处理。在此，感谢ExcelTip.Net站长Apolloh的支持，感谢本站点所有人**绿色风（QQ:79664738)**的支持与奉献，特此鸣谢！
------本人网名**KevinChengCW（QQ:1210618015)**原ExcelTip.Net总版主之一

评论列表